Pesquisa personalizada

Um dos grandes diferenciais de um pacote de aplicativos como o Office está no fato dele possuir sua própria linguagem de programação. Utilizando esta linguagem pode-se automatizar/personalizar determinadas tarefas de forma a que o Office se encaixe perfeitamente na rotina de cada empresa.

E se você desejasse criar uma linguagem de programação para sua própria aplicação, como deveria fazer ?

O Visual Basic disponibiliza um componente chamado Script Control, que pode ser incluido na aplicação através de Project->Components->Microsoft Script Control 1.0

Este componente executa instruções em VBScript que sejam transmitidas para ele. Desta forma podemos criar uma linguagem de macros para a aplicação.

Para a criação da linguagem de macros precisamos seguir algumas regras :

1) Para que a linguagem de macros possa ter acesso às funções e informações normais da aplicação é importante que todo o núcleo de código da aplicação esteja criado em um modelo de classes. Assim sendo a interface da aplicação não deverá realizar as tarefas chaves da aplicação mas sim chamar as classes. As mesmas classes poderão ser chamadas de dentro da linguagem de macros.

2) O VBSCript não possui tipagem de variáveis. Por isso todas as classes do modelo de objetos que forem chamadas pelo VBScript precisam ter os parâmetros de subs e funções definidos como ByVal. Caso seja necessário um parâmetro ByRef este precisará ser Variant. Lembre-se sempre que o default do VB é ByRef.

3) Se for necessário que a linguagem de macros acesse algum form na interface este deverá ser carregado (Load) antes da execução da macro. Deve-se tomar cuidado com as questões de carregamento/descarregamento e destruição de forms.

Vamos demonstrar a criação de uma linguagem de macros com uma aplicação/exemplo.

Nossa aplicação será uma aplicação MDI. Terá 2 forms, além do MDI : frmCalculo, que realiza uma soma de 2 números e frmMacro, utilizado para a construção de macros.

A aplicação possui ainda uma classe CL_CALCULAR com um método somar. O form frmCalculo não realiza a soma, utiliza a classe CL_CALCULAR para realizar a mesma.

Veja o código do método Somar da classe CL_CALCULAR :

Public Function Somar(ByVal a As Integer, ByVal b As Integer) As Integer

Somar = a + b
End Function

Observe o ByVal necessário na especificação dos parâmetros dos métodos, como explicado anteriormente.

No formulário frmMacro colocaremos uma textbox (txtMacro) com MultiLine=true para que o usuário possa realizar a digitação da macro. Neste form acrescentaremos também o Script Control, que chamaremos de SC, e um botão cmdExecutar, responsável pela execução da macro.

Agora chegamos ao ponto principal : a execução da macro. Para que a macro possa acessar a classe e o formulário de calculo precisaremos adiciona-los no objeto SC. Para adicionarmos o form teremos que carrega-lo, enquanto que no caso da classe ela precisará ser instanciada.

Ao adicionar os objetos podemos definir o nome com o qual serão conhecidos dentro da linguagem de macro, que pode ser qualquer coisa, não precisa ser igual ao nome interno da aplicação. 

Feito isso basta adicionarmos o código e executar. A execução é feita com base em Subs. Executa-se uma sub contida na macro. Desta forma a macro deverá possuir uma Sub que será chamada pela aplicação. Podemos definir a Sub principal como sendo Sub Main.

Veja como fica o código :

Private Sub cmdExecutar_Click()
On Error GoTo Trataerro
Dim obj As CL_CALCULAR

'Cria/carrega os objetos para o ambiente de macro
Set obj = New CL_CALCULAR
Load frmCalculo

'Adiciona os objetos no ambiente de macro
SC.AddObject "Calcular", obj, True
SC.AddObject "TelaCalculo", frmCalculo, True

'Adiciona o código e executa
SC.AddCode txtMacro.Text
SC.Run "Main"

'Desfaz o ambiente de macro
Set obj = Nothing
Unload frmCalculo
Set frmCalculo = Nothing

'Desfaz os vínculos no objeto SC
SC.Reset
Exit Sub

Trataerro:
'Tratamento de erros no script
MsgBox "Erro no Script"
End Sub

Veja alguns exemplos de macro que podem ser criadas em tempo de execução :

Exemplo 1 :

Sub Main()
TelaCalculo.Show 1
End sub

Exemplo 2 :

Sub Main()
x=inputbox("Digite o 1o número")
y=inputbox("Digite o 2o número")
msgbox Calcular.somar(x,y)
End Sub

Observe que apesar da aplicação ser MDI, o frmCalculo, utilizado pela macro, não é MDI Child, o que permite que a macro chame-o de forma modal.

Essa aplicação é apenas um exemplo da criação de macros, mostrando desta forma o tópico principal : A execução da macro. Para implementar isso em sua aplicação o ideal é criar um banco de dados para armazenar macros e uma tela de listagem das macros neste banco, a partir da qual seja possível executar as macros ou edita-las. Pode-se também criar um sistema de agendamento e/ou um sistema de eventos para a execução das macros.

Baixe o código fonte referente a este artigo.

Dennes Torres
MCSD,MCSE,MCDBA

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
Conheça mais sobre o nosso site :

• Visite nossa área de artigos técnicos
• Conheça nossas dicas técnicas (mais de 300 dicas)
• Conheça nosso fórum de discussões
• Conheça nossa área de download com muitos componentes e códigos úteis
• Conheça nosso treinamento de lógica de programação on-line
• Conheça nossa prova de certificação em VB (oferecemos certificado aos aprovados)

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::