Pesquisa personalizada

Utilizando DataShape : Criando Hierarquias em código

Já há muitas versões o ADO possui um recurso conhecido como Data Shapping.

O Data Shapping é um Provider especial que permite que os dados sejam acessados através de outro provider (do sql server, por exemplo) e posteriormente manipulados no client através do provider de datashape. Com isso podemos, por exemplo, gerar um relacionamento de tabelas no client, simplificando eventualmente alguns algorítmos.

Deve-se porém estar sempre ciente de que este código está sendo processado no client, consequentemente todos os registros são levados para o client para que o processamento seja realizado. Com volumes pequenos isso se torna uma grande ferramenta de desenvolvimento, mas deve-se tomar muito cuidado com quando usar ou não este recurso.

Podemos iniciar nosso código fazendo um references para o ADO e definindo variáveis no general do formulário da seguinte forma :

dim cn as new connection
dim rspub as new recordset

Em seguida vamos iniciar a carga dos dados no LOAD do form. Vamos analisar as instruções por partes :

Dim SQL as string
cn.Provider = "MSDataShape"
cn.Open "data provider=sqloledb;server=.;uid=sa;pwd=;initial catalog=pubs"

Observe a forma como especificamos um provider como MSDATASHAPE e nos parâmetros passamos a informação data provider como sendo sqloledb, ou seja, estamos no fundo utilizando 2 providers, um para fazer o acesso a banco e o MSDataShape para os tratamentos especiais no client.

SQL = "SHAPE {SELECT * FROM publishers} APPEND " & _
"({SELECT * FROM titles} AS PubTitles " & _
"RELATE pub_id TO pub_id)"

Eis a montagem da instrução SQL, se é que podemos chamar assim. Na verdade é uma instrução de SHAPE que será interpretada pelos provider MSDATASHAPE, que retirará desta instrução as devidas instruções SQL para serem enviadas ou 2o provider.

Observem que temos duas instruções SQL básicas, uma da tabela PAI, outra da tabela FILHO. Com a combinação da das instruções APPEND e RELATE fazemos o relacionamento entre as tabelas pai e filho, observe a indicação da relação entre chave primária e estrangeira utilizada na instrução.

A indicação AS PubTitles tem uma finalidade muito especial. O recordset com os registros relacionados será obtido através de um campo do recordset principal. A indicação AS PubTiles indica o nome deste campo no recordset.

Para exibir os dados vamos utilizar uma textbox para exibir o nome da editora (tabela publishers) e uma listbox para exibir o nome dos títulos (tabela titles). Acrescentaremos na interface dois botões, Próximo e anterior, para realizar a movimentação pelo recordset. Vamos também enfeitar com um label para nos mostrar o registro atual.

Vamos criar uma função que será chamada a cada movimentação para refazer a exibição dos dados. A 1a chamada desta função fica então sendo no form_load, junto com a abertura do recordset, veja :

rsPub.Open SQL, cn, adOpenStatic, adLockReadOnly, adCmdText
ExibeRegistro

Veja então como ficou o código completo do form_load :

Sub Form_load
   Dim SQL as string
   cn.Provider = "MSDataShape"
   cn.Open "data provider=sqloledb;server=.;uid=sa;pwd=;initial catalog=pubs"
   SQL = "SHAPE {SELECT * FROM publishers} APPEND " & _
   "({SELECT * FROM titles} AS PubTitles " & _
   "RELATE pub_id TO pub_id)"
   rsPub.Open SQL, cn, adOpenStatic, adLockReadOnly, adCmdText
   ExibeRegistro
End Sub

O código dos botões cmdNext e cmdPrev é muito simples :

sub cmdNext_click()
   rspub.movenext
   if rspub.eof then
   rspub.moveprevious
   end if
   ExibeRegistro
end sub

Sub cmdPrev_click()
   rspub.moveprevious
   if rspub.bof then
   rspub.movenext
   end if
   ExibeRegistro
end sub

Vamos então montar a sub ExibeRegistro, que nos mostrará como acessar os dados relacionados :

   Sub ExibeRegistro()
	   dim rstit as recordset

	 'Preenche o nome da editora
	   txteditora.text=rspub.fields("pub_name")

	 'apaga a lista de livros
	   lstlivros.clear
   
	   'Obtem o recordset de títulos
	   set rstit=rspub.fields("pubtitles").value
   
   	do while not rstit.eof
		   lstlivros.addnew rstit.fields("title").value
		   rstit.movenext
	   loop

		 lblReg=rspub.absoluteposition    & "/" & rspub.recordcount
   end sub

Com este exemplo montamos uma interface simples para manipular registros utilizando o recurso de shapping. Aproveite este recurso !

[]'s

Dennes Torres
MCSD,MCSE,MCDBA

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
Conheça mais sobre o nosso site :

• Visite nossa área de artigos técnicos
• Conheça nossas dicas técnicas (mais de 300 dicas)
• Conheça nosso fórum de discussões
• Conheça nossa área de download com muitos componentes e códigos úteis
• Conheça nosso treinamento de lógica de programação on-line
• Conheça nossa prova de certificação em VB (oferecemos certificado aos aprovados)

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::